[Date Prev][Date Next][Thread Prev][Thread Next][Date Index][Thread Index]
[commits] r8534 - in /fsf/trunk/libc: ./ csu/ sysdeps/x86_64/ sysdeps/x86_64/multiarch/

To: commits@xxxxxxxxxx
Subject: [commits] r8534 - in /fsf/trunk/libc: ./ csu/ sysdeps/x86_64/ sysdeps/x86_64/multiarch/
From: eglibc@xxxxxxxxxx
Date: Sat, 06 Jun 2009 07:08:52 -0000
Author: eglibc
Date: Sat Jun  6 00:08:51 2009
New Revision: 8534

Log:
Import glibc-mainline for 2009-06-06

Added:
    fsf/trunk/libc/sysdeps/x86_64/multiarch/ifunc-defines.sym
    fsf/trunk/libc/sysdeps/x86_64/multiarch/rawmemchr.S
    fsf/trunk/libc/sysdeps/x86_64/multiarch/strlen.S
Modified:
    fsf/trunk/libc/ChangeLog
    fsf/trunk/libc/csu/elf-init.c
    fsf/trunk/libc/sysdeps/x86_64/multiarch/Makefile
    fsf/trunk/libc/sysdeps/x86_64/multiarch/init-arch.h
    fsf/trunk/libc/sysdeps/x86_64/rawmemchr.S

Modified: fsf/trunk/libc/ChangeLog
==============================================================================
--- fsf/trunk/libc/ChangeLog (original)
+++ fsf/trunk/libc/ChangeLog Sat Jun  6 00:08:51 2009
@@ -1,3 +1,18 @@
+2009-06-05  Ulrich Drepper  <drepper@xxxxxxxxxx>
+
+	* sysdeps/x86_64/rawmemchr.S: Minor optimization.
+
+	* sysdeps/x86_64/multiarch/rawmemchr.S: New file.
+
+	* sysdeps/x86_64/multiarch/strlen.S: New file.
+	* sysdeps/x86_64/multiarch/ifunc-defines.sym: New file.
+	* sysdeps/x86_64/multiarch/Makefile: Add rule to build ifunc-defines.h.
+	* sysdeps/x86_64/multiarch/init-arch.h: Name structure with register
+	content.
+
+	* csu/elf-init.c: Only compile in IFUNC functionality if USE_MULTIARCH
+	is defined.
+
 2009-06-04  Ulrich Drepper  <drepper@xxxxxxxxxx>
 
 	* sysdeps/x86_64/strlen.S: Minor optimizations.

Modified: fsf/trunk/libc/csu/elf-init.c
==============================================================================
--- fsf/trunk/libc/csu/elf-init.c (original)
+++ fsf/trunk/libc/csu/elf-init.c Sat Jun  6 00:08:51 2009
@@ -1,5 +1,5 @@
 /* Startup support for ELF initializers/finalizers in the main executable.
-   Copyright (C) 2002, 2003, 2004, 2005 Free Software Foundation, Inc.
+   Copyright (C) 2002, 2003, 2004, 2005, 2009 Free Software Foundation, Inc.
    This file is part of the GNU C Library.
 
    The GNU C Library is free software; you can redistribute it and/or
@@ -36,7 +36,7 @@
 
 #include <stddef.h>
 
-#ifndef LIBC_NONSHARED
+#if defined USE_MULTIARCH && !defined LIBC_NONSHARED
 # include <link.h>
 # include <dl-irel.h>
 
@@ -80,7 +80,7 @@
   /* For dynamically linked executables the preinit array is executed by
      the dynamic linker (before initializing any shared object.  */
 
-#ifndef LIBC_NONSHARED
+#if defined USE_MULTIARCH && !defined LIBC_NONSHARED
 # ifdef ELF_MACHINE_IRELA
   {
     const size_t size = __rela_iplt_end - __rela_iplt_start;

Modified: fsf/trunk/libc/sysdeps/x86_64/multiarch/Makefile
==============================================================================
--- fsf/trunk/libc/sysdeps/x86_64/multiarch/Makefile (original)
+++ fsf/trunk/libc/sysdeps/x86_64/multiarch/Makefile Sat Jun  6 00:08:51 2009
@@ -1,3 +1,4 @@
 ifeq ($(subdir),csu)
 aux += init-arch
+gen-as-const-headers += ifunc-defines.sym
 endif

Added: fsf/trunk/libc/sysdeps/x86_64/multiarch/ifunc-defines.sym
==============================================================================
--- fsf/trunk/libc/sysdeps/x86_64/multiarch/ifunc-defines.sym (added)
+++ fsf/trunk/libc/sysdeps/x86_64/multiarch/ifunc-defines.sym Sat Jun  6 00:08:51 2009
@@ -1,0 +1,15 @@
+#include "init-arch.h"
+#include <stddef.h>
+
+--
+
+CPU_FEATURES_SIZE	sizeof (struct cpu_features)
+KIND_OFFSET		offsetof (struct cpu_features, kind)
+CPUID_OFFSET		offsetof (struct cpu_features, cpuid)
+CPUID_SIZE		sizeof (struct cpuid_registers)
+CPUID_EAX_OFFSET	offsetof (struct cpuid_registers, eax)
+CPUID_EBX_OFFSET	offsetof (struct cpuid_registers, ebx)
+CPUID_ECX_OFFSET	offsetof (struct cpuid_registers, ecx)
+CPUID_EDX_OFFSET	offsetof (struct cpuid_registers, edx)
+
+COMMON_CPUID_INDEX_1

Modified: fsf/trunk/libc/sysdeps/x86_64/multiarch/init-arch.h
==============================================================================
--- fsf/trunk/libc/sysdeps/x86_64/multiarch/init-arch.h (original)
+++ fsf/trunk/libc/sysdeps/x86_64/multiarch/init-arch.h Sat Jun  6 00:08:51 2009
@@ -35,7 +35,7 @@
       arch_kind_other
     } kind;
   int max_cpuid;
-  struct
+  struct cpuid_registers
   {
     unsigned int eax;
     unsigned int ebx;

Added: fsf/trunk/libc/sysdeps/x86_64/multiarch/rawmemchr.S
==============================================================================
--- fsf/trunk/libc/sysdeps/x86_64/multiarch/rawmemchr.S (added)
+++ fsf/trunk/libc/sysdeps/x86_64/multiarch/rawmemchr.S Sat Jun  6 00:08:51 2009
@@ -1,0 +1,93 @@
+/* Copyright (C) 2009 Free Software Foundation, Inc.
+   Contributed by Ulrich Drepper <drepper@xxxxxxxxxx>.
+   This file is part of the GNU C Library.
+
+   The GNU C Library is free software; you can redistribute it and/or
+   modify it under the terms of the GNU Lesser General Public
+   License as published by the Free Software Foundation; either
+   version 2.1 of the License, or (at your option) any later version.
+
+   The GNU C Library is distributed in the hope that it will be useful,
+   but WITHOUT ANY WARRANTY; without even the implied warranty of
+   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
+   Lesser General Public License for more details.
+
+   You should have received a copy of the GNU Lesser General Public
+   License along with the GNU C Library; if not, write to the Free
+   Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
+   02111-1307 USA.  */
+
+#include <sysdep.h>
+#include <ifunc-defines.h>
+
+
+/* Define multiple versions only for the definition in lib.  */
+#ifndef NOT_IN_libc
+	.text
+ENTRY(rawmemchr)
+	.type	rawmemchr, @gnu_indirect_function
+	cmpl	$0, __cpu_features+KIND_OFFSET(%rip)
+	jne	1f
+	call	__init_cpu_features
+1:	leaq	__rawmemchr_sse2(%rip), %rax
+	testl	$(1<<20), __cpu_features+CPUID_OFFSET+COMMON_CPUID_INDEX_1*CPUID_SIZE+CPUID_ECX_OFFSET(%rip)
+	jz	2f
+	leaq	__rawmemchr_sse42(%rip), %rax
+2:	ret
+END(rawmemchr)
+strong_alias (rawmemchr, __rawmemchr)
+
+
+	.align 	16
+	.type	__rawmemchr_sse42, @function
+__rawmemchr_sse42:
+	cfi_startproc
+	CALL_MCOUNT
+	movd	%esi, %xmm1
+	movq	%rdi, %rcx
+	punpcklbw %xmm1, %xmm1
+	andq	$~15, %rdi
+	punpcklbw %xmm1, %xmm1
+	orl	$0xffffffff, %esi
+	movdqa	(%rdi), %xmm0
+	pshufd	$0, %xmm1, %xmm1
+	subq	%rdi, %rcx
+	pcmpeqb	%xmm1, %xmm0
+	shl	%cl, %esi
+	pmovmskb %xmm0, %ecx
+	movl	$16, %eax
+	movl	$16, %edx
+	andl	%esi, %ecx
+	jnz	1f
+
+2:	pcmpestri $0x08, 16(%rdi), %xmm1
+	leaq	16(%rdi), %rdi
+	jnc	2b
+
+	leaq	(%rdi,%rcx), %rax
+	ret
+
+1:	bsfl	%ecx, %eax
+	addq	%rdi, %rax
+	ret
+	cfi_endproc
+	.size	__rawmemchr_sse42, .-__rawmemchr_sse42
+
+
+# undef ENTRY
+# define ENTRY(name) \
+	.type __rawmemchr_sse2, @function; \
+	__rawmemchr_sse2: cfi_startproc; \
+	CALL_MCOUNT
+# undef END
+# define END(name) \
+	cfi_endproc; .size __rawmemchr_sse2, .-__rawmemchr_sse2
+# undef libc_hidden_builtin_def
+/* It doesn't make sense to send libc-internal rawmemchr calls through a PLT.
+   The speedup we get from using SSE4.2 instruction is likely eaten away
+   by the indirect call in the PLT.  */
+# define libc_hidden_builtin_def(name) \
+	.globl __GI___rawmemchr; __GI___rawmemchr = __rawmemchr_sse2
+#endif
+
+#include "../rawmemchr.S"

Added: fsf/trunk/libc/sysdeps/x86_64/multiarch/strlen.S
==============================================================================
--- fsf/trunk/libc/sysdeps/x86_64/multiarch/strlen.S (added)
+++ fsf/trunk/libc/sysdeps/x86_64/multiarch/strlen.S Sat Jun  6 00:08:51 2009
@@ -1,0 +1,93 @@
+/* strlen(str) -- determine the length of the string STR.
+   Copyright (C) 2009 Free Software Foundation, Inc.
+   Contributed by Ulrich Drepper <drepper@xxxxxxxxxx>.
+   This file is part of the GNU C Library.
+
+   The GNU C Library is free software; you can redistribute it and/or
+   modify it under the terms of the GNU Lesser General Public
+   License as published by the Free Software Foundation; either
+   version 2.1 of the License, or (at your option) any later version.
+
+   The GNU C Library is distributed in the hope that it will be useful,
+   but WITHOUT ANY WARRANTY; without even the implied warranty of
+   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
+   Lesser General Public License for more details.
+
+   You should have received a copy of the GNU Lesser General Public
+   License along with the GNU C Library; if not, write to the Free
+   Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
+   02111-1307 USA.  */
+
+#include <sysdep.h>
+#include <ifunc-defines.h>
+
+
+/* Define multiple versions only for the definition in libc and for
+   the DSO.  In static binaries we need strlen before the initialization
+   happened.  */
+#if defined SHARED && !defined NOT_IN_libc
+	.text
+ENTRY(strlen)
+	.type	strlen, @gnu_indirect_function
+	cmpl	$0, __cpu_features+KIND_OFFSET(%rip)
+	jne	1f
+	call	__init_cpu_features
+1:	leaq	__strlen_sse2(%rip), %rax
+	testl	$(1<<20), __cpu_features+CPUID_OFFSET+COMMON_CPUID_INDEX_1*CPUID_SIZE+CPUID_ECX_OFFSET(%rip)
+	jz	2f
+	leaq	__strlen_sse42(%rip), %rax
+2:	ret
+END(strlen)
+
+
+	.align 	16
+	.type	__strlen_sse42, @function
+__strlen_sse42:
+	cfi_startproc
+	CALL_MCOUNT
+	pxor	%xmm2, %xmm2
+	movq	%rdi, %rcx
+	movq	%rdi, %r8
+	andq	$~15, %rdi
+	movdqa	%xmm2, %xmm1
+	pcmpeqb	(%rdi), %xmm2
+	orl	$0xffffffff, %esi
+	subq	%rdi, %rcx
+	shll	%cl, %esi
+	pmovmskb %xmm2, %edx
+	andl	%esi, %edx
+	jnz	1f
+
+2:	pcmpistri $0x08, 16(%rdi), %xmm1
+	leaq	16(%rdi), %rdi
+	jnz	2b
+
+	leaq	(%rdi,%rcx), %rax
+	subq	%r8, %rax
+	ret
+
+1:	subq	%r8, %rdi
+	bsfl	%edx, %eax
+	addq	%rdi, %rax
+	ret
+	cfi_endproc
+	.size	__strlen_sse42, .-__strlen_sse42
+
+
+# undef ENTRY
+# define ENTRY(name) \
+	.type __strlen_sse2, @function; \
+	__strlen_sse2: cfi_startproc; \
+	CALL_MCOUNT
+# undef END
+# define END(name) \
+	cfi_endproc; .size __strlen_sse2, .-__strlen_sse2
+# undef libc_hidden_builtin_def
+/* It doesn't make sense to send libc-internal strlen calls through a PLT.
+   The speedup we get from using SSE4.2 instruction is likely eaten away
+   by the indirect call in the PLT.  */
+# define libc_hidden_builtin_def(name) \
+	.globl __GI_strlen; __GI_strlen = __strlen_sse2
+#endif
+
+#include "../strlen.S"

Modified: fsf/trunk/libc/sysdeps/x86_64/rawmemchr.S
==============================================================================
--- fsf/trunk/libc/sysdeps/x86_64/rawmemchr.S (original)
+++ fsf/trunk/libc/sysdeps/x86_64/rawmemchr.S Sat Jun  6 00:08:51 2009
@@ -34,19 +34,18 @@
 	pcmpeqb	%xmm1, %xmm0
 	shl	%cl, %esi
 	pmovmskb %xmm0, %ecx
-	leaq	16(%rdi), %rdi
 	andl	%esi, %ecx
 	jnz	1f
 
-2:	movdqa	(%rdi), %xmm0
+2:	movdqa	16(%rdi), %xmm0
 	leaq	16(%rdi), %rdi
 	pcmpeqb	%xmm1, %xmm0
 	pmovmskb %xmm0, %ecx
 	testl	%ecx, %ecx
 	jz	2b
 
-1:	bsfl	%ecx, %ecx
-	leaq	-16(%rcx,%rdi), %rax
+1:	bsfl	%ecx, %eax
+	addq	%rdi, %rax
 	ret
 END (rawmemchr)
Prev by Date: [commits] r8531 - in /fsf/trunk/libc: ChangeLog sysdeps/x86_64/strlen.S
Next by Date: [commits] r8547 - in /fsf/trunk/libc: ChangeLog dlfcn/dlfcn.h libio/fileops.c localedata/ChangeLog localedata/locales/ur_IN
Previous by thread: [commits] r8531 - in /fsf/trunk/libc: ChangeLog sysdeps/x86_64/strlen.S
Next by thread: [commits] r8547 - in /fsf/trunk/libc: ChangeLog dlfcn/dlfcn.h libio/fileops.c localedata/ChangeLog localedata/locales/ur_IN
Index(es):
- Date
- Thread